'--- 행/열 크기 설정

Option Explicit

'--- 행/열 크기 설정

Sub Sample084()

    Sheets("Sheet1").Select

    Rows("2").RowHeight = 25

    Columns("C:D").ColumnWidth = 20

End Sub

'--- 자동으로 행/열 크기 설정

Sub Sample085()

    Sheets("Sheet1").Select

    With Range("B2:E9")

        .Rows.AutoFit

        .Columns.AutoFit

    End With

End Sub

'--- 행/열 숨기기

Sub Sample086()

    Sheets("Sheet1").Select

    If Columns("B").Hidden = True Then

        Columns("B").Hidden = False

    Else

        Columns("B").Hidden = True

    End If

    'Columns("B").Hidden = Not Columns("B").Hidden

End Sub

'--- 셀 삽입하기

Sub Sample087()

    Sheets("Sheet2").Select

    Range("B3:D3").Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow

End Sub

'--- 3행마다 셀 삽입하기

Sub Sample088()

    Sheets("Sheet2").Select

    Dim intA As Integer, intB As Integer

    intB = Range("B2").CurrentRegion.Rows.Count

    Range("B2").Select

    For intA = 1 To (intB - 2) \ 3

        ActiveCell.Offset(4).Select

        ActiveCell.EntireRow.Insert

    Next

End Sub

'--- 특정 행 위에 행 삽입하기

Sub Sample089()

    Sheets("Sheet3").Select

    Dim intA As Integer, intB As Integer

    intB = Range("B2").CurrentRegion.Rows.Count + 1

    For intA = intB To 3 Step -1

        Cells(intA, 2).Select

        If ActiveCell Like "*강의실" Then

            ActiveCell.EntireRow.Insert

            ActiveCell.EntireRow.ClearFormats

        End If

    Next

End Sub

'--- 셀 삭제하기

Sub Sample090()

    Sheets("Sheet4").Select

    Selection.Delete xlShiftUp

End Sub

'--- 조건에 맞는 행 삭제하기

Sub Sample091()

    Sheets("Sheet5").Select

    Dim intA As Integer, intB As Integer

    intB = Range("B2").CurrentRegion.Rows.Count + 1

    For intA = intB To 3 Step -1

        Cells(intA, "D").Select

        If ActiveCell = 0 Then ActiveCell.EntireRow.Delete

    Next

End Sub

'--- 중복 값 제거하기

Sub Sample092()

    Sheets("Sheet6").Select

    Range("B2:E10").RemoveDuplicates Array(2, 3), xlYes

End Sub

'--- 셀 범위 복사하기

Sub Sample093()

    Sheets("Sheet7").Select

    Range("B2:D6").Copy Range("F2")

    Range("B2:D6").Copy Range("B8")

    Range("B2:D6").Copy Range("F8")

End Sub

'--- 셀 범위 이동하기

Sub Sample094()

    Sheets("Sheet8").Select

    Range("B2:D2").Copy Range("F2")

    Range("B8:D10").Cut Range("F3")

End Sub

'--- 클립보드 내용 붙여넣기

Sub Sample095()

    Sheets("Sheet9").Select

    Range("B2:D6").Copy

    ActiveSheet.Paste Range("F2")

    Range("F8").Select

    ActiveSheet.Paste

End Sub

'--- 선택하여 붙여넣기

Sub Sample096()

    Sheets("Sheet10").Select

    Range("B2:D6").Copy

    Range("F2").PasteSpecial xlPasteFormats

    Range("F8").PasteSpecial xlPasteValues

    Application.CutCopyMode = False

End Sub

'--- 일괄적으로 5000씩 더하기

Sub Sample097()

    Sheets("Sheet11").Select

    Range("G3").Copy

    Range("E3:E9").PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd

    'Range("E3:E9").PasteSpecial xlPasteValues, xlPasteSpecialOperationSubtract

    Application.CutCopyMode = False

End Sub

'--- 행/열 바꿔서 붙여넣기

Sub Sample098()

    Sheets("Sheet12").Select

    Range("B2:D5").Copy

    Range("B7").PasteSpecial Transpose:=True

    Range("B7").PasteSpecial , , , True

    Application.CutCopyMode = False

End Sub

'--- 데이터 찾기

Sub Sample099()

    Sheets("Sheet13").Select

    Dim rngSource As Range, rngFind As Range

    Set rngSource = Range("B2").CurrentRegion.Columns(3)

    Set rngFind = rngSource.Find(Range("H2"))

    If Not rngFind Is Nothing Then

        Range("G5") = rngFind.Offset(, -1)

        Range("H5") = rngFind.Offset(, 1)

    Else

        Range("G5:H5").ClearContents

        MsgBox "데이터를 찾을 수 없습니다."

    End If

End Sub

'--- 다음 데이터 찾기

Sub Sample100()

    Sheets("Sheet14").Select

    Dim rngSource As Range, rngFind As Range

    Dim strAddress As String, intRow As Integer

    Set rngSource = Range("B2").CurrentRegion.Columns(2)

    Set rngFind = rngSource.Find(Range("H2"))

    If Not rngFind Is Nothing Then

        strAddress = rngFind.Address

        intRow = 5

        Do

            Cells(intRow, "G") = rngFind.Offset(, 1)

            Cells(intRow, "H") = rngFind.Offset(, 2)

            intRow = intRow + 1

            Set rngFind = rngSource.FindNext(rngFind)

        Loop Until rngFind.Address = strAddress

    Else

        Range("G5:H9").ClearContents

    End If

End Sub

'--- 데이터 찾아 바꾸기

Sub Sample101()

    Sheets("Sheet15").Select

    Range("B2:D6").Replace "Excel", "Excel 2010"

End Sub

'--- 서식을 찾아 바꾸기

Sub Sample102()

    Sheets("Sheet15").Select

    With Application.FindFormat

        .Clear

        .Interior.Color = RGB(255, 255, 0)

    End With

    With Application.ReplaceFormat

        .Clear

        .Interior.Color = RGB(255, 153, 255)

        .Font.Bold = True

    End With

    Range("B2:D6").Replace "", "", SearchFormat:=True, ReplaceFormat:=True

End Sub