'--- 셀 또는 범위 참조하기

Option Explicit

'--- 셀 또는 범위 참조하기

Sub Sample019()

    '시트를 지정하지 않으면 현재 시트에 결과가 나타납니다.

    Sheets("Sheet1").Select

    Range("B2") = "VBA"

    Range("C2:E5") = "Power"

    Range("B2, C2:E5").HorizontalAlignment = xlCenter

End Sub

'--- 행과 열 번호로 셀 참조하기

Sub Sample020()

    Cells.Clear

    Cells(2, 2) = "VBA"

    Range(Cells(2, 3), Cells(5, 5)) = "Power"

    Range("B2:E5").Cells(2, 3) = "Excel"

End Sub

'--- 셀의 선택과 활성화

Sub Sample021()

    Range("B2:E5").Select

    Selection = "Cheer"

    Range("C4").Activate

    ActiveCell = "UP!!"

End Sub

'--- O행 O열 떨어진 셀 참조

Sub Sample022()

    Dim rngCell As Range

    For Each rngCell In Sheets("Sheet2").Range("C3:C7")

        rngCell.Offset(0, 1) = Year(rngCell)

        rngCell.Offset(0, 2) = Month(rngCell)

    Next

End Sub

'--- 상하좌우 마지막 셀까지 참조하기

Sub Sample023()

    Sheets("Sheet3").Select

    Range("B2").End(xlDown).Font.ColorIndex = 3

    Range("B2", Range("B2").End(xlToRight)).Select

End Sub

'--- 현재 영역 참조하기

Sub Sample024()

    Range("C5").Activate

    ActiveCell.CurrentRegion.Font.ColorIndex = 5

End Sub

'--- 현재 영역의 크기 조절

Sub Sample025()

    Dim rngA As Range, intRow As Integer

    Set rngA = Range("B2").CurrentRegion

    intRow = rngA.Rows.Count

    rngA.Offset(1, 0).Resize(intRow - 1).Select

End Sub

'--- 사용 영역 참조하기

Sub Sample026()

    Sheets("Sheet4").Select

    Range("B2").CurrentRegion.Select

    MsgBox "B2 셀이 있는 현재 영역입니다."

    ActiveSheet.UsedRange.Select

    MsgBox "현재 시트의 전체 사용 영역입니다."

End Sub

'--- 여러 범위 참조하기

Sub Sample027()

    Dim rngA As Range, rngB As Range

    Sheets("Sheet5").Select

    Set rngA = Range("B3:B7, G3:G7")

    Set rngB = Union(Range("B2:G2"), Range("B8:G8"))

    rngA.Font.Bold = True

    rngB.Interior.ColorIndex = 4

End Sub

'--- 셀 유형에 따라 참조하기

Sub Sample028()

    Range("B2").CurrentRegion.SpecialCells(xlCellTypeFormulas).Select

    MsgBox "수식이 들어 있는 셀입니다."

    Range("B2").CurrentRegion.SpecialCells(xlCellTypeFormulas, xlNumbers).Select

    MsgBox "수식의 결과가 숫자인 셀입니다."

End Sub

'--- 셀 주소 알아내기

Sub Sample029()

    Dim strMsg As String

    If TypeName(Selection) = "Range" Then

        strMsg = Selection.Address

        strMsg = strMsg & vbCr & Selection.Address(True, False)

        strMsg = strMsg & vbCr & Selection.Address(False, True)

        strMsg = strMsg & vbCr & Selection.Address(False, False)

    End If

    MsgBox strMsg

End Sub

'--- 다중 범위 안의 영역 개수

Sub Sample030()

    Dim i As Integer, intCount As Integer, strMsg As String

    If TypeName(Selection) = "Range" Then

        intCount = Selection.Areas.Count

        For i = 1 To intCount

            strMsg = strMsg & Selection.Areas(i).Address & vbCr

        Next

    End If

    MsgBox strMsg

End Sub

'--- 행과 열 참조하기

Sub Sample031()

    Dim rngA As Range

    Sheets("Sheet6").Select

    Set rngA = Range("B2:G8")

    rngA.Rows(1).Interior.ColorIndex = 6

    Columns("C:F").ColumnWidth = 7

End Sub

'--- 현재 행/열 참조하기

Sub Sample032()

    Dim rngCell As Range

    Sheets("Sheet6").Select

    For Each rngCell In Range("G3:G7")

        If rngCell >= 20000 Then

            rngCell.EntireRow.Font.ColorIndex = 7

            rngCell.EntireRow.Font.Bold = True

        End If

    Next

End Sub